Overview

This package provides an implementation to interact with Kafka Brokers via Kafka Consumer and Kafka Producer clients.

Apache Kafka is an open-source distributed event streaming platform used for high-performance data pipelines, streaming analytics, data integration, and mission-critical applications.

This package supports Kafka 1.x.x and 2.0.0 versions.

Consumer and producer

Kafka producer

A Kafka producer is a Kafka client that publishes records to the Kafka cluster. The producer is thread-safe and sharing a single producer instance across threads will generally be faster than having multiple instances. When working with a Kafka producer, the first thing to do is to initialize the producer. For the producer to execute successfully, an active Kafka broker should be available.

The code snippet given below initializes a producer with the basic configuration.

1import ballerinax/kafka;
2
3kafka:ProducerConfiguration producerConfiguration = {
4    clientId: "basic-producer",
5    acks: "all",
6    retryCount: 3
7};
8
9kafka:Producer kafkaProducer = check new (kafka:DEFAULT_URL, producerConfiguration);

Kafka consumer

A Kafka consumer is a subscriber responsible for reading records from one or more topics and one or more partitions of a topic. When working with a Kafka consumer, the first thing to do is initialize the consumer. For the consumer to execute successfully, an active Kafka broker should be available.

The code snippet given below initializes a consumer with the basic configuration.

1kafka:ConsumerConfiguration consumerConfiguration = {
2    groupId: "group-id",    // Unique string that identifies the consumer
3    offsetReset: "earliest",    // Offset reset strategy if no initial offset
4    topics: ["kafka-topic"]
5};
6
7kafka:Consumer kafkaConsumer = check new (kafka:DEFAULT_URL, consumerConfiguration);

Listener

The Kafka consumer can be used as a listener to a set of topics without the need to manually poll the messages.

You can use the Caller to manually commit the offsets of the messages that are read by the service. The following code snippet shows how to initialize and define the listener and how to commit the offsets manually.

1kafka:ConsumerConfiguration consumerConfiguration = {
2    groupId: "group-id",
3    topics: ["kafka-topic-1"],
4    pollingInterval: 1,
5    autoCommit: false
6};
7
8listener kafka:Listener kafkaListener = new (kafka:DEFAULT_URL, consumerConfiguration);
9
10service on kafkaListener {
11    remote function onConsumerRecord(kafka:Caller caller, kafka:ConsumerRecord[] records) {
12        // processes the records
13        ...
14        // commits the offsets manually
15        kafka:Error? commitResult = caller->commit();
16
17        if commitResult is kafka:Error {
18            log:printError("Error occurred while committing the offsets for the consumer ", 'error = commitResult);
19        }
20    }
21}

Data serialization

Serialization is the process of converting data into a stream of bytes that is used for transmission. Kafka stores and transmits these bytes of arrays in its queue. Deserialization does the opposite of serialization in which bytes of arrays are converted into the desired data type.

Currently, this package only supports the byte array data type for both the keys and values. The following code snippets show how to produce and read a message from Kafka.

1string message = "Hello World, Ballerina";
2string key = "my-key";
3// converts the message and key to a byte array
4check kafkaProducer->send({ topic: "test-kafka-topic", key: key.toBytes(), value: message.toBytes() });

1kafka:ConsumerRecord[] records = check kafkaConsumer->poll(1);
2
3foreach var kafkaRecord in records {
4    byte[] messageContent = kafkaRecord.value;
5    // tries to generate the string value from the byte array
6    string result = check string:fromBytes(messageContent);
7    io:println("The result is : ", result);
8}

Concurrency

In Kafka, records are grouped into smaller units called partitions. These can be processed independently without compromising the correctness of the results and lays the foundation for parallel processing. This can be achieved by using multiple consumers within the same group each reading and processing data from a subset of topic partitions and running in a single thread.

Topic partitions are assigned to consumers automatically or you can manually assign topic partitions.

The following code snippet joins a consumer to the consumer-group and assigns it to a topic partition manually.

1kafka:ConsumerConfiguration consumerConfiguration = {
2    // `groupId` determines the consumer group
3    groupId: "consumer-group",
4    pollingInterval: 1,
5    autoCommit: false
6};
7
8kafka:Consumer kafkaConsumer = check new (kafka:DEFAULT_URL, consumerConfiguration);
9// creates a topic partition
10kafka:TopicPartition topicPartition = {
11    topic: "kafka-topic-1",
12    partition: 1
13};
14// passes the topic partitions to the assign function as an array
15check kafkaConsumer->assign([topicPartition]);

Report issues

To report bugs, request new features, start new discussions, view project boards, etc., go to the Ballerina standard library parent repository.

Useful links

• Chat live with us via our Discord server.
• Post all technical questions on Stack Overflow with the #ballerina tag.