ballerina/data.csv Ballerina library

Parse a byte[] as a subtype of record {}[] or anydata[][].

byte[] csvBytes = check io:fileReadBytes("example.csv");
record {int id; string name;}[] csv1 = check csv:parseBytes(csvBytes);
[int, string][] csv2 = check csv:parseBytes(csvBytes);
record {|int id;|}[] csv3 = check csv:parseBytes(csvBytes);
record {int id;}[] csv4 = check csv:parseBytes(csvBytes, {skipLines: [1]});

Parse a string array of array as a subtype of record {}[] or anydata[][].

string[][] csvList = [["1", "John"], ["2", "Jane"]];
[int, string][] csv1 = check csv:parseList(csvList);
record {|int id;|}[] csv2 = check csv:parseList(csvList, {customHeaders: ["id", "name"]});
record {int id;}[] csv3 = check csv:parseList(csvList, {skipLines: [1], customHeaders: ["id", "name"]});

Parse a CSV byte block stream as a subtype of record {}[] or anydata[][].

stream<byte[], io:Error?> csvByteStream = check io:fileReadBlocksAsStream("example.csv");
record {int id; string name;}[] csv1 = check csv:parseStream(csvByteStream);
stream<byte[], io:Error?> csvByteStream2 = check io:fileReadBlocksAsStream("example.csv");
[int, string][] csv2 = check csv:parseStream(csvByteStream2);
stream<byte[], io:Error?> csvByteStream3 = check io:fileReadBlocksAsStream("example.csv");
record {|int id;|}[] csv3 = check csv:parseStream(csvByteStream3);
stream<byte[], io:Error?> csvByteStream4 = check io:fileReadBlocksAsStream("example.csv");
record {int id;}[] csv4 = check csv:parseStream(csvByteStream4, {skipLines: [1]});

Parse a CSV string as a subtype of record {}[] or anydata[][].

string csvString = string `id,name
                           1,John
                           3,Jane`;
record {int id; string name;}[] csv1 = check csv:parseString(csvString);
[int, string][] csv2 = check csv:parseString(csvString);
record {|int id;|}[] csv3 = check csv:parseString(csvString);
record {int id;}[] csv4 = check csv:parseString(csvString, {skipLines: [1]});

Transform value of type record {}[] to subtype of record {}[] or anydata[][].

record {int id; string name;}[] csvRecords = [{id: 1, name: "John"}, {id: 2, name: "Jane"}];
[int, string][] csv1 = check csv:transform(csvRecords);
record {|int id;|}[] csv2 = check csv:transform(csvRecords);
record {int id;}[] csv3 = check csv:transform(csvRecords, {skipLines: [1]});